SAS中的SQL语句完全教程之一：SQL简介与基本查询功能

本系列全部内容主要以《SQL Processing with the SAS System (Course Notes)》为主进行讲解，本书是在网上下载下来的，但忘了是在哪个网上下的，故不能提供下载链接了，需要的话可以发邮件向我索取，我定期邮给大家，最后声明一下所有资料仅用于学习，不得用于商业目的，否则后果自负。

转载请注明出处：http://blog.sina.com.cn/s/blog_5d3b177c0100cksl.html

1 SQL过程步介绍
1.1 SQL过程步可以实现下列功能：
查询SAS数据集、从SAS数据集中生成报表、以不同方式实现数据集合并、创建或删除SAS数据集、视图、索引等、更新已存在的数据集、使得SAS系统可以使用SQL语句、可以和SAS的数据步进行替换使用。注意，SQL过程步并不是用来代替SAS数据步，也不是一个客户化的报表工具，而是数据处理用到的查询工具。

1.2 SQL过程步的特征
SQL过程步并不需要对每一个查询进行重复、每条语句都是单独处理、不需要print过程步就能打印出查询结果、也不用sort过程步进行排序、不需要run、要quit来结束SQL过程步

1.3 SQL过程步语句
SELECT：查询数据表中的数据
ALTER：增加、删除或修改数据表的列
CREATE：创建一个数据表
DELETE：删除数据表中的列
DESCRIBE：列出数据表的属性
DROP：删除数据表、视图或索引
INSERT：对数据表插入数据
RESET：没用过，不知道什么意思
SELECT：选择列进行打印
UPDATE：对已存在的数据集的列的值进行修改


2 SQL基本查询功能

2.1 SELECT语句基本语法介绍
SELECT object-item <, ...object-item>
FROM from-list

>

>;
这里SELECT：指定被选择的列
FROM：指定被查询的表名
WHERE：子数据集的条件
GROUP BY：将数据集通过group进行分类
HAVING：根据GROUP BY的变量得到数据子集
ORDER BY：对数据集进行排序

2.2 SELECT语句的特征
选择满足条件的数据、数据分组、对数据进行排序、对数据指定格式、一次最多查询32个表。这里还要提到的就是，在SAS系统中，对于表名和变量名一般不超过32个字符，对于库名，文件引用名，格式等不能超过8个字符

2.3 Validate关键字
Validate关键字只存在于select语句中、可以在不运行查询的情况下测试语句的语法、检查列名是否合法、对于不正确的查询将打印其消息。例：
1 proc sql;
2 validate
3 select Region, Product,Sales
4 from sashelp.shoes
5 where Region = 'Africa';
NOTE: PROC SQL 语句有有效语法。
6 quit;
此外，我们还可以用noexec选项也可以用来进行语法测试。例：
7 proc sql noexec;
8 select Region, Product,Sales
9 from sashelp.shoes
10 where Region = 'Africa';
NOTE: 由于 NOEXEC 选项，未执行语句。
11 quit;
这里提示未执行，未提示错误，说明该语句没有语法错误。但是如果加入一个sashelp.shoes表里没有字段，这里就会出现错误，例：
12 proc sql noexec;
13 select Region, Product,Sales,test
14 from sashelp.shoes
15 where Region = 'Africa';
ERROR: 以下这些列在起作用的表中没有找到: test.
16 quit;

2.4 查询列
我们可以像2.3那样查询指定列，也可以用*来查询所有列。例：
proc sql;
select *
from sashelp.shoes;
quit;
这里我们可以用feedback选项来查看到底我们选择了哪些列：
17 proc sql feedback;
18 select *
19 from sashelp.shoes;
NOTE: Statement transforms to:
select SHOES.Region, SHOES.Product, SHOES.Subsidiary, SHOES.Stores, SHOES.Sales, SHOES.Inventory, SHOES.Returns
from SASHELP.SHOES;
20 quit;
这时，我们可以看到从sashelp.shoes表中选择了8个列

2.5 消除重复值
我们可以用distinct选项来消除重复值。例如，我们要得到没有重复的所有地区的名称：
proc sql;
select distinct Region
from sashelp.shoes
quit;

2.6 where子集查询
2.6.1 比较运算符
先列出where语句用到的比较运算符：
LT < 小于 GT > 大于
EQ = 等于
LE <= 小于或等于 GE >= 大于或等于
NE ^= 不等于
例如，我们要查询sales大于100000的所有数据：
proc sql;
select *
from sashelp.shoes
where sales>100000;
quit;

2.6.2 in：只要满足in里的任意一个值，表达式即为真，例如，我们要选择Region在Africa和Eastern Europe的所有数据：
proc sql;
select *
from sashelp.shoes
where Region in ('Africa','Eastern Europe');
quit;

2.6.3 逻辑运算符
OR | 或
AND & 是
NOT ^ 非
例如，选择Region在Africa和Eastern Europe，且销售额大于100000的所有数据：
proc sql;
select *
from sashelp.shoes
where Region in ('Africa','Eastern Europe') and sales>100000;
quit;

2.6.4 CONTAINS或?：判断某列是否包含指定字符串
例如，选择列Region包含’Afr’的数据：
proc sql;
select *
from sashelp.shoes
where Region ? 'Afr';
quit;

2.6.5 IS NULL或IS MISSING：判断某列数据是否为空
例如，如果找出Region为空的数据：
proc sql;
select *
from sashelp.shoes
where Region is missing;
quit;
注意，这里我们还可以用以下表达式对where语句进行替换。如果region为数值型变量，则可以用region=.，如果region为字符型变量，则可以用region= ‘’进行替换。

2.6.6 Between and：选择某一区间的数据
例如选择sales大于100000，但小于200000的所有数据：
proc sql;
select *
from sashelp.shoes
where sales between 100000 and 200000;
quit;

2.6.7 like：判断是否能匹配某些字符
例如，选择以region以A开头的所有地区
proc sql;
select *
from sashelp.shoes
where Region like 'A%';
quit;
这里注意有两类通配符，‘%’可以通配任意个任意字符，‘_’只能通配一个任意字符

2.6.8 =*：类似匹配
这里由于sashelp.shoes里没有符合要求的数据，所有就用书上的例子说明一下吧：
Where lastname=* ‘smith’，出来的结果可能是：smith，smythe等

2.7 表达式
我们可以通过已有的列进行计算来得到新的列，这时用关键词as来给新的列赋列名，例如：
proc sql;
select Region, Product,Sales,Stores,Sales/Stores as salesperstores
from sashelp.shoes
quit;
这时结果就会多一列salesperstores，用来得到该地区该产品每个商店的平均销售量。这里要注意的是，在创建表达式时，我们还可以在SQL里用到SAS中的除LAG和DIFF之外的所有函数。

这里我们还可以用表达式计算出来的结果来进行子集查询，但一定要记住用calculated关键词。例如我们要找出商店平均销售量大于5000的数据：
方法一：
proc sql;
select Region, Product,Sales,Stores,Sales/Stores as salesperstores
from sashelp.shoes
where Sales/Stores>5000;
quit;
方法二：
proc sql;
select Region, Product,Sales,Stores,Sales/Stores as salesperstores
from sashelp.shoes
where calculated salesperstores>5000;
quit;

2.8 查询结果展示
2.8.1 order by数据排序
默认的排序方式是升序，我们可以用DESC关键词来进行降序排列。例如以sales降序排列数据：
proc sql;
select *
from sashelp.shoes
order by Sales DESC;
quit;
这里提示一下，我们可以用任意多列进行排序，包括表达式结果（不用calculated），但最好是选择的列。

2.8.2 LABEL与FORMAT
LABEL：改变输出变量名的内容
FORMAT：改变列的值的输出方式
例如，改变salesperstores的label和format
proc sql;
select Region, Product,Sales,Stores,
Sales/Stores as salesperstores
label='sales per stores'
format=dollar12.2
from sashelp.shoes;
quit;

2.9 处理SQL常用函数
MEAN或AVG：均值
COUNT或N或FREQ：非缺失值个数
MAX：最大值
MIN：最小值
NMISS：缺失值个数
STD：标准差
SUM：求和
VAR：方差

2.9.1 求和sum
proc sql;
select Region, Product,Sales,Stores,
sum(Sales,Inventory,Returns) as total
from sashelp.shoes;
quit;

2.9.2 求均值avg
proc sql;
select Region, Product,Sales,Stores,
avg(Sales) as salesavg
from sashelp.shoes;
quit;

2.9.3 分组求均值group by
proc sql;
select Region,
avg(Sales) as salesavg
from sashelp.shoes
group by Region;
quit;

2.9.4 计数count
proc sql;
select Region,count(*) as count
from sashelp.shoes
group by Region;
quit;

2.9.5 HAVING数据子集
proc sql;
select Region,count(*) as count
from sashelp.shoes
group by Region
having count(*)>50;
quit;
其它的就不多作介绍了，多用用就熟悉了

2.10子查询
2.10.1 找出regions平均sales大于全部平均sales的region
proc sql;
select Region,
avg(Sales) as salesavg
from sashelp.shoes
group by Region
having avg(Sales)>
(select avg(Sales) from sashelp.shoes);
quit;

2.10.2 ANY关键词介绍
>ANY(20,30,40) 最终效果：>20
ALL (20,30,40) 最终效果：>40
例如，选择出region为united state的sales小于所有region为africa的sales的数据
proc sql;
select Region,Sales
from sashelp.shoes
where Region='United States'
and Sales (select Sales from sashelp.shoes where Region='Africa');
quit;

2.10.4 EXISTS与NOT EXISTS
proc sql;
select *
from sashelp.shoes
where exists
(select * from sashelp.orsales);
quit;